Essays, Posts & Presentations

Truncated Fock Space as a Way to Model 2nd Quantization in Wolfram Language

Juraj Tkáč

Author

Juraj Tkáč

Title

Truncated Fock Space as a Way to Model 2nd Quantization in Wolfram Language

Description

Trying to investigate properties of truncated Fock space.

Truncated Fock Space as a Way to Model 2nd Quantization in Wolfram Language

JURAJ TKÁČ

In this project, we were exploring truncated Fock space as a way to model 2nd quantization in Wolfram Language. We went through different states, in particular coherent and CAT states, visualized their properties, with the purpose of providing a good insight into their meaning. That can lead to discovery of larger area of quantum computation based on CAT qubits, which look as promising natural error correcting frameworks towards universal quantum computation. As it is a new area in research, they were not well established in wolfram language yet, particularly in wolfram quantum framework paclet, that already handles significant states like Bell States, GHZ states et cetera.

In[206]:=

PacletInstall["Wolfram/QuantumFramework"]

Out[206]=

PacletObject

Name: Wolfram/QuantumFramework

Version: 1.4.2



In[207]:=

Needs["Wolfram`QuantumFramework`"];

Theory

Quantum mechanics uses Hilbert space for the description of information that is included in its space. This Hilbert space could be said: “contains vectors, from which each of them represents state.” This is the one of the main differences between classical and quantum mechanics. In classical we have phase space, that means each position, point contains the information about the states. Question is what does it mean if we go down to the level of quantum mechanics, what means that we have vectors in infinite dimensional Hilbert space, that is interesting because it means we use multiplication of vectors, inner product so some projection similarity of spaces, maybe some natural pairing or comparing of each other to each other and we know we can superpone them but cannot achieve something new apart from the space as it is there. That is in essence what some term algebra in some terminological field means. Set of rules which defines the possible phenomena. But in fact as the theorem of Emma Noether basically says: “Every kind of asymmetry is phenomena.” So we need to consider precise algebra and also some uncertainty for raising phenomenas. But how to encode it? By complex unpredictable behaviour. If we go further on the higher scales we have only points in the phase space. It is multidimensional space according to the density of objects we have. There is Liouville´s theorem that states that: “preservation of the density of states in the space happen.” This is in opposite with quantum field theory where particles in some space can be created or annihilated by nature and mathematically by application of creation or annihilation operators. But before we dive into these, we will go further and on even higher scales we have 4 dimensional curved spacetime in principle. States are there represented by 4-vectors, vectors with four components that contain space and time together. Evolution/motion of the states is represented by worldline(geodesics) in that curved spacetime and that curved spacetime is dependent on the Metric tensor that is being curved by Mass-Energy Tensor. In Quantum field theory formalism appearing Creation and annihilation operators, which are mathematical operators that have widespread applications in quantum mechanics, notably in the study of quantum harmonic oscillators and many-particle systems.[1] An annihilation operator (usually denoted



lowers the number of particles in a given state by one. A creation operator (usually denoted

†



) increases the number of particles in a given state by one, and it is the adjoint of the annihilation operator. In many subfields of physics and chemistry, the use of these operators instead of wavefunctions is known as second quantization. They were introduced by Paul Dirac.[2] For simulation of the properties of quantum harmonic oscillator we have to choose some class of states, in this work we concentrate on Coherent states.
Coherent state is the most closest one to the classical state. Because causally, when we work with some quantum states and acting on them with number operator as on fields we obtain mean value of photons as zero. Scientists wanted to obtain non-zero value, find the minima of uncertainty , so they have tried to find eigenvalue of annihilation operator. They have found some solution of reccurence equation and it was just coherent state, which is special type of Fock state (vector from Fock space, which is tensor product of Hilbert spaces) that is achieved thanks to number representational approach of quantum field theory and especially the theory of second quantization. Its position operator mean values are oscillating sinusoidally like classical electric field, and amplitudes are also similar to that case.

Initialization Definitions

Random complex number with certain absolute value

In[338]:=

GenerateRandomComplexWithNorm[desiredNorm_]:=Module[{theta},theta=RandomReal[{0,2Pi}];desiredNorm*(Cos[theta]+ISin[theta])]

Coherent state of size d with amplitude α

In[339]:=

coherentStateNN[α_,d_]:=QuantumState[Table[1*α^n/Sqrt[Factorial[n]],{n,0,d-1}],d]

Creation and annihilation operator of size n

In[340]:=

creationAnnihilation[n_]:=Module[{ca,aa},aa=QuantumOperator[Table[If[i==j+1,Sqrt[i-1],0],{i,1,n},{j,1,n}],n];ca=aa["Dagger"];{ca,aa}]

Particular nth Fock state in a basis of size d

In[341]:=

fockN[n_,d_]:=QuantumState[SparseArray[{n+1->1},d],d]

Introduction

It would be appropriate to learn about field as itself. In terms of formalism, every field is represented by operator. But we cannot forget the particular approach. Luckily we can derive that particles are excitations of fields, so it is coherent in terms of physical approach. Apart from that, there are of course quantum states on which are operators being applied, as we are in Hilbert space, they respect such properties. One of the most interesting states is coherent state:

α

α

∞

∑

n0

n

α

†



|0

†



|0D(α)|0

These alphas are complex amplitudes and n in the square root, is sum over the elements, n in the bra-ket is the dimensionality of the state, exponentiation is the normalization factor. Second term in this set of equations means start to the definition of Displacement operator which then leads to the D(α) which is the exact definition of displacement operator. This operator plays an important role in quantum optics for translating the state in phase space. This approach is possible thanks to the part of second quantization direction in the quantum theory. Second quantization means that going from individual particles description to the fields or many-body particles descriptions. So we have to consider that particles are being moved from the systems or taken to the systems. Key part as was already mentioned are creation and annihilation operators. These operators obey some properties, like commutation relations, which are important for photons, as they are bosons, particles with spin 1. (for fermions hold anticommutational relations, because they have spin 1/2). These commutation relations reflecting indistinguishability. It ensures, that wavefunctions of bosonic particles are symmetric with respect to the exchange of any two particles. Main goal is to explore truncated Fock space. (Fock space that is not infinite-dimensional but finite). This space is natural setting for such formalism, because creation and annihilation operators are defined to act on states within this space. Let´s choose some concrete arbitrary dimensionality n to represent truncated Fock space.

In[212]:=

n=20;

In[213]:=

{qaa,qca}=creationAnnihilation[n]

Out[213]=

QuantumOperator

Pure map
Dimension: 20→20	Order: {1}→{1}

,QuantumOperator

Pure map
Dimension: 20→20	Order: {1}→{1}



In[214]:=

fockN[19,20]

Out[214]=

QuantumState

Pure state	Qudits: 1
Type: Vector	Dimension: 20



In[215]:=

α=RandomComplex[]

Out[215]=

0.864947+0.459315

In[216]:=

nnca=coherentStateNN[α,n]

Out[216]=

(1.+0. )|0〉+(0.864947+0.459315 )|1〉+(0.379831+0.561843 )|2〉+(0.0406865+0.381298

)|3〉+(-0.069972+0.174245 )|4〉+(-0.0628583+0.0530277 )|5〉+(-0.0321395+

0.00693792 )|6〉+(-0.0117115-0.00331144 )|7〉+(-0.00304368-0.00291451 )|8〉

+(-0.000431314-0.0013063 )|9〉+(0.0000717648-0.000419947 )|10〉+(0.0000768736-

0.00009958 )|11〉+(0.0000323981-0.0000146711 )|12〉+(9.64104×

-6

+6.07726×

-7

)|13〉+(2.15409×

-6

+1.32399×

-6

)|14〉+(3.2405×

-7

+5.51148×

-7

)|15〉

+(6.78387×

-9

+1.56389×

-7

)|16〉+(-1.59986×

-8

+3.3563×

-8

)|17〉+(-6.89522×

-9

+5.11045×

-9

)|18〉+(-1.90674×

-9

+2.87502×

-10

)|19〉

In[217]:=

nca=nnca["Normalize"]

Out[217]=

QuantumState

Pure state	Qudits: 1
Type: Vector	Dimension: 20



It should hold that



|α 〉 =α |α〉

In[218]:=

z=qaa[nca]

Out[218]=

QuantumState

Pure state	Qudits: 1
Type: Vector	Dimension: 20



In[219]:=

z["Norm"]

Out[219]=

0.979338

In[220]:=

y=α*nca

Out[220]=

QuantumState

Pure state	Qudits: 1
Type: Vector	Dimension: 20



In[221]:=

(z["Amplitudes"]//Values)-(y["Amplitudes"]//Values)//Most//Chop

Out[221]=

{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0}

In[222]:=

nca["Norm"]

Out[222]=

In[223]:=

nca["ProbabilityPlot"]

Out[223]=

Hamiltonian

One of the most important operators in quantum mechanics is Hamiltonian, which describes total amount of energy of the system. In some situations it is possible to divide it into kinetic and potential energy terms like H = T + V. In this particular context are used field excitations, described by quantum harmonic oscillator Hamiltonian.

In[224]:=

no=qca[qaa]

Out[224]=

QuantumOperator

Pure map
Dimension: 20→20	Order: {1}→{1}



In[225]:=

Hamiltonian=hω(no+1/2QuantumOperator["I"[n]])

Out[225]=

QuantumOperator

Pure map
Dimension: 20→20	Order: {1}→{1}



After that we are capable of applying that operator on appropriate state with same dimensionality:

In[226]:=

Hamiltonian[fockN[15,n]]

Out[226]=

QuantumState

Pure state	Qudits: 1
Type: Vector	Dimension: 20



Photon-distribution plots

After we have prepared appropriate definitions of coherent states and pseudorandom generator of complex alphas that generates pseudo-randomly in order to represent the non-biased experimental statistics, we can define come concrete states and plot them:

In[227]:=

{nca1,nca2,nca3}=Table[coherentStateNN[GenerateRandomComplexWithNorm[i],20]["Normalize"],{i,3}]

Out[227]=

QuantumState

Pure state	Qudits: 1
Type: Vector	Dimension: 20

,QuantumState

Pure state	Qudits: 1
Type: Vector	Dimension: 20

,QuantumState

Pure state	Qudits: 1
Type: Vector	Dimension: 20



In[350]:=

legend=SwatchLegend[{Green,Red},{"Quantum Probability Distribution","Poisson Distribution"}];plot1=Show[{nca1["ProbabilityPlot",TicksStyle->8,ImagePadding->15,ChartStyle->Green,ChartLabels->(Style[StringForm["|``〉",#],6]&/@Range[0,19])],DiscretePlot[PDF[PoissonDistribution[1],x-1],{x,1,13},PlotStyle->{Red,Thick}]}];plot7=Legended[plot1,Placed[legend,Right]]

Out[352]=

	Quantum Probability Distribution
	Poisson Distribution

As we can see, the probability distribution perfectly matches Poisson behaviour which is fitted on that Quantum Probability Distribution. This behaviour comes from the nature of derivation of these expressions. Deeper reasons are out of the main scope of this work, we take them as granted based on calculations.

In[353]:=

legend=SwatchLegend[{Yellow,Red},{"Quantum Probability Distribution","Poisson Distribution"}];plot2=Show[{nca2["ProbabilityPlot",TicksStyle->8,ImagePadding->15,ChartStyle->Yellow,ChartLabels->(Style[StringForm["|``〉",#],6]&/@Range[0,19])],DiscretePlot[PDF[PoissonDistribution[4],x-1],{x,1,20},PlotStyle->{Red,Thick}]}];plot5=Legended[plot2,Placed[legend,Right]]

Out[355]=

	Quantum Probability Distribution
	Poisson Distribution

In[356]:=

legend=SwatchLegend[{Blue,Red},{"Quantum Probability Distribution","Poisson Distribution"}];plot3=Show[{nca3["ProbabilityPlot",TicksStyle->8,ImagePadding->15,ChartStyle->Blue,ChartLabels->(Style[StringForm["|``〉",#],6]&/@Range[0,19])],DiscretePlot[PDF[PoissonDistribution[9],x-1],{x,1,20},PlotStyle->{Red,Thick}]}];plot9=Legended[plot3,Placed[legend,Right]]

Out[358]=

	Quantum Probability Distribution
	Poisson Distribution

In[359]:=

legend=SwatchLegend[{Green,Yellow,Blue},{"|α| = 1","|α| = 2","|α| = 3"}];plot4=Show[plot1,plot2,plot3,PlotRange->All];Legended[plot4,Placed[legend,Right]]

Out[362]=

We can see that probabilities with increasing norms are shifting to the higher states. In fact for the higher norms it doesn´t make sense to continue because we should consider alphas squared maximally, so the metric for our calculations should be maximal number that is squared and still smaller or equal to the dimensionality of such system. What does it mean we operate with dimensionality? It means we could preserve more information and stay protected against the noise, if we are further evolving that state. For this calculation it is just our chosen model that we work with 20, we just wanted to see, how truncated Fock space behaves.

Displacement operator, HamiltonianEvolve, PositionOperator

Displacement operator definition

This type of unitary operator:

is acting on the state in order to shift it to the concrete vector alpha to some point alpha in the phase space. We are dealing here with optical phase space which is handy for providing insight into the class of quantum optical states, such as coherent state is. It preserves properties of state to be coherent that we are going to verify by next lines of code: At first we define exponent of the coherent state

In[241]:=

c=α*qca-Conjugate[α]*qaa

Out[241]=

QuantumOperator

Pure map
Dimension: 20→20	Order: {1}→{1}



After that we can create displacement operator. We have two possible options as states the equation for matrix exponentiation :

and we also want to see how fast each method is:

In[242]:=

disop2=QuantumOperator[MatrixExp[c["Matrix"]],20];//AbsoluteTiming

Out[242]=

{0.0672125,Null}

In[243]:=

In[245]:=

disop=QuantumOperator[Exp[QuantumOperator[c]],n];//AbsoluteTiming

Out[245]=

{0.0962794,Null}

In[246]:=

disop["Matrix"]-disop2["Matrix"]

Out[246]=

SparseArray

Specified elements: 400

Dimensions: {20,20}



By that we can see that results are some, but computational power needed for that was different:

In[247]:=

%//Normal//Chop

Out[247]=

{{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0}}

Verification of the coherent state

As we already know coherent state has to satisfy the eigenvalue equation for annihilation operator. We also know that construction of the coherent state from the displacement operator acting on the vacuum state is possible, so let´s try the calculations and see how it can be proven to work. At first we apply displacement operator on vacuum state:

In[248]:=

displacedVacuum=disop[]

Out[248]=

QuantumState

Pure state	Qudits: 1
Type: Vector	Dimension: 20



Then we verify the difference between these amplitudes of these state, we use chop function in order to reduce possible small numbers which can be handled by computer with difficulties, and could be neglected for our purposes:

In[249]:=

(displacedVacuum["AmplitudeList"]-nca["AmplitudeList"])//Chop

Out[249]=

{0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0}

Quantum Evolution of the state and mean position operator

States aren´t rigid phenomenas so we have to capture also the evolution of them and that is generally achieved by applying time-dependent Hamiltonian.

In[250]:=

QOE=QuantumOperator[QuantumEvolve[Hamiltonian/h,None,t],"Parameters"->t]

Out[250]=

QuantumOperator

Pure map
Dimension: 20→20	Order: {1}→{1}



For example for time 1 in general units, which we are going to further consider as seconds, we obtain quantum evolution operator:

In[251]:=

QOE[1]

Out[251]=

QuantumOperator

Pure map
Dimension: 20→20	Order: {1}→{1}



Then we apply it on the normalized coherent state with time interval starting from zero to ten by timestep 0.25 in order to achieve nicer and proper visualization of that phenomena:

In[252]:=

states=Table[QOE[n][nca],{n,0,10,0.25}];

In[253]:=

Clear[h,m,ω]

In[254]:=

positionoperator=QuantumOperator[Sqrt[h/(mω)](qaa+qca)]

Out[254]=

QuantumOperator

Pure map
Dimension: 20→20	Order: {1}→{1}



In[255]:=

meanPosition=((#["Dagger"]@positionoperator@#)["Scalar"]&)/@states;

In[336]:=

ListLinePlot[Transpose[{Range[0,10,0.25],Re[meanPosition/.{h->1,m->1,ω->1}]}],Mesh->Full,Frame->True,FrameLabel->{"Time(s)","

mω

units"},PlotStyle->Red]

Out[336]=

Now we can see the oscillating behaviour of mean value of position operator, which is sinusoidal and is pretty close to the classical behaviour of plain wave in electromagnetism as we have stated in the introduction.

Symbolic evolution for coherent state

For the future use-cases we would also like to verify it works for general state, so we consider symbolic evaluation of the state like that

|β

- ω t

〉

In[257]:=

QOE

Out[257]=

QuantumOperator

Pure map
Dimension: 20→20	Order: {1}→{1}



In[258]:=

symbolicCoherent=coherentStateNN[β,20]

Out[258]=

QuantumState

Pure state	Qudits: 1
Type: Vector	Dimension: 20



In[259]:=

QOE[symbolicCoherent]

Out[259]=

QuantumState

Pure state	Qudits: 1
Type: Vector	Dimension: 20



In[260]:=

coherentStateNN[β

-ωt



,20]

Out[260]=

QuantumState

Pure state	Qudits: 1
Type: Vector	Dimension: 20



Then we can see that if we apply some exponential term to that amplitudes and compare it with the state without it, we observe that states are actually same up to the global phase, because wolfram quantum framework recognizes such classes of states as same.

In[261]:=

%==%%

Out[261]=

True,

-tω



β

-t



β,

-2tω





-2t



-3tω





-3t



-4tω





-4t



-5tω





-5t



-6tω





-6t



-7tω





-7t



-8tω





-8t



-9tω





-9t



-10tω



720



-10t



720

-11tω



720



-11t



720

-12tω



1440

231



-12t



1440

231

-13tω



1440

3003



-13t



1440

3003

-14tω



10080

858



-14t



10080

858

-15tω



30240

1430



-15t



30240

1430

-16tω



120960

1430



-16t



120960

1430

-17tω



120960

24310



-17t



120960

24310

-18tω



725760

12155



-18t



725760

12155

-19tω



725760

230945



-19t



725760

230945



CAT states

Because of strong principle of superposition, which simply means that when the state is appropriate and the other is also appropriate for the sol\bution of Schrödinger´s equation, then the sum of these states is also solution. It can be useful for creation of Cat states

The states, which are superpositions of two coherent states of opposite directions. We will be constructing coherent state for the not normalized coherent state nnca, which is concrete CAT state:

In[312]:=

coherentStateNN[-α,20]

Out[312]=

(1.+0. )|0〉+(-0.864947-0.459315 )|1〉+(0.379831+0.561843 )|2〉+(-0.0406865-0.381298

)|3〉+(-0.069972+0.174245 )|4〉+(0.0628583-0.0530277 )|5〉+(-0.0321395+

0.00693792 )|6〉+(0.0117115+0.00331144 )|7〉+(-0.00304368-0.00291451 )|8〉

+(0.000431314+0.0013063 )|9〉+(0.0000717648-0.000419947 )|10〉+(-0.0000768736+

0.00009958 )|11〉+(0.0000323981-0.0000146711 )|12〉+(-9.64104×

-6

-6.07726×

-7

)|13〉+(2.15409×

-6

+1.32399×

-6

)|14〉+(-3.2405×

-7

-5.51148×

-7

)|15〉

+(6.78387×

-9

+1.56389×

-7

)|16〉+(1.59986×

-8

-3.3563×

-8

)|17〉+(-6.89522×

-9

+5.11045×

-9

)|18〉+(1.90674×

-9

-2.87502×

-10

)|19〉

This particular state contain only even amplitudes, as could be visible in next plot, that is caused by definition of such even CAT state, as is stated above.

CATstatehistogram=QuantumState[coherentStateNN[-α,20]+nnca,20]["ProbabilityPlot"]

Out[337]=

Apart from that there exists also definition with odd terms:

In[363]:=

CATstatehistogram2=QuantumState[coherentStateNN[-α,20]-nnca,20]["ProbabilityPlot"]

Out[363]=

This framework could be generalized for further use for any particular coherent state and CAT state needed.

Concluding Remarks

As a summary, we were working on exploration of truncated Fock space in terms of it´s states, basis and dimensionality. That included second quantization approach in terms of definition creation and annihilation operators for our randomly explicitly specified 20-dimensional Fock state, but we have prepared general framework for any dimensionality of truncated Fock space wanted.
From that state we have constructed coherent state and verified it is the eigenstate of annihilation operator. For that coherent state we have got Poisson distribution that naturally arises from the derivation of such formulas. In terms of 20-dimensional state we have tried three different pseudorandom complex numbers, and for each verified that it respects the Poisson behaviour. We have also defined Hamiltonian in terms of formalism of creation and annihilation operators, which we have used for evolution of the state, either symbolically, or with concrete values. Plot of the mean value of position operator is function of time and oscillating sinusoidally with respect to the time. So it is corresponding to the theory of coherent states that their behaviour shows plain wave properties. Additionally we have defined displacement operator and verified it creates coherent state from vacuum state. After that we were easily be capable have prepared basic platform for preparation of CAT states, that are building units of CAT qubits.

Future approach could be then: Implement these CAT qubits in Wolfram Quantum framework and use it´s functionalities for measurements the photon number and amount of bit-flips and phase-flips occured. Because these qubit in terms of hardware are specially encoded into superconducting resonator system that is using 2-photon dissipation mechanism to get rid of the entropy which is gained by some random bit flip, that means we obtain natural error correction and by “leaking” the heat information we stabilize desired computational information without the additional manipulation. Analogy of that is simple classical light switch with energy barrier between states created by spring, which should be deformed. [3] If it randomly switches, entropy of the system raised and we have to reduce it, so we need to leak that entropy into some well in order to come back to the wanted state. These qubits are being intensively studied among large variety of scientists because of their natural error correction - exponential supression of bit-flips but linear increase of phase flips, which raises with square of the photon number.

Acknowledgments

I would like to thank especially my mentor Bruno Tenorio, for his great advice to problem solving, in terms of theory and coding. Next I would like to thank my main Mentor Mads Bahrami for patient and firm leadership that led to the great workflow. Additionally I would like to thank also to Xerxes Arsiwalla and Hatem Elshatlawy for their theoretical advice.

References

Feynman, Richard P. (1998) [1972]. Statistical Mechanics: A Set of Lectures (2nd ed.). Reading, Massachusetts: Addison-Wesley. ISBN 978-0-201-36076-9.

Dirac, P. A. M. (1927). “The quantum theory of the emission and absorption of radiation”, Proc Roy Soc London Ser A, 114 (767), 243-265

Lescanne, R et al. (2019) “Exponential suppression of bit-flips in a qubit encoded in an oscillator.” Nature Physics 16: 509-513.

Cite This Notebook

“Truncated Fock space as a way to model 2nd quantization in Wolfram Language”
by Juraj Tkáč
Community Post Link

Cite this as: Juraj Tkáč, "Truncated Fock Space as a Way to Model 2nd Quantization in Wolfram Language" from the Notebook Archive (2024), https://notebookarchive.org/2024-07-48hd33l